@yogthos @yogthos

Who doesn't love a good low contrast photo?

sudo apt install openttd

title: "FRIENDLY COMPUTERS BASIC LISTING VOLUME 00" author: Blair Vidak

\newpage

FRIENDLY COMPUTERS CORPORATION

"A company that actually exists".

https://gravatar.com/comradevidak

\newpage

README


Welcome to the first volume of the Friendly Computers Corporation
BASIC Program Listings!

Things to note:

# We recommend using VICE emulator.

# We recommend loading this VIC-20 PRG into emulator first.

# Hard mode: Don't, and type the program straight in!

# Patience Is A Virtue!

\newpage

ALIEN ATTACK

VIC-20

3K

alien attack 3k.prg ==0401==

1 poke 51,255:poke 52,19:poke 55,255:poke 56,19:clr
2 data 0,0,0,8,8,8,8,8
3 data 24,24,24,24,24,60,60,60
4 data 0,0,0,16,16,16,16,16
5 data 9,11,15,15,31,63,0,0
6 data 144,208,240,240,248,252,0,0
7 data 126,255,255,255,255,153,24,0
8 data 0,0,0,0,24,24,24,24
9 data 24,24,24,24,24,24,60,60
10 data 24,25,31,31,31,24,24,24
11 data 126,255,255,255,255,60,24,24
12 data 24,152,248,248,248,24,24,24
13 data 0,0,24,126,255,255,66,0
14 data 0,24,24,24,24,24,0,0
15 data 0,12,28,60,56,48,0,0
16 data 1,144,4,80,2,88,0,33
17 data 0,0,76,16,72,48,180,64
18 data 128,2,64,8,0,64,4,0
19 data 200,129,0,8,0,2,97,0
20 data 24,24,24,24,24,24,24,24
21 data 0,0,0,0,0,0,0,0
22 data 0,0,0,0,24,24,24,24
23 for i=0 to 512
24 poke 5120+i,peek(32768+i):next i
25 for i=0 to 167
26 read x:poke 5632+i,x:nexti
27 poke 36869,253:poke 36879,110
28 data 0,0,0,24,24,24,24
29 s$="{SHIFT-*}AB↓{left}{left}{left}CED"
30 print "{clr}":m$="     alien attack":p$="{wht}{home}↓↓↓↓↓":gosub 89
31 m$="  written for vic-20":p$="{wht}{home}↓↓↓↓↓↓↓":gosub 89
32 m$="     by a.e.webb":p$="{wht}{home}↓↓↓↓↓↓↓↓↓↓↓":gosub 89
33 m$="    instructions?":p$="{home}{wht}↓↓↓↓↓↓↓↓↓↓↓↓↓↓":gosub 89
34 get a$:if a$="" then 34
35 if a$="y" then 94
36 ti$="000000"
37 dd=1:ss=7680:of=30720:sc=0
38 sp=ss:print"{clr}"
39 poke sp,32
40 sp=sp+dd
41 if sp=7680 then dd=1
42 if sp=7701 then dd=-1
43 de=300-sc*5:if de<0 then de=0
44 if ti>de and fl=0 then 59
45 poke sp,75:poke sp+of,1
46 for xx=sp+22 to sp+220 step 22
47 if peek(xx)=65 or peek(xx)=71 then 71
48 next
49 get a$
50 if a$="_" and sp<>7680 and sp<>7701 then dd=-dd:goto 39
51 if a$=" " and fl=0 then fl=1:q9=sp:bp=q9+22
52 if fl=0 then 39
53 poke bp,32
54 bp=bp+22
55 if peek(bp)<>32 then 62
56 poke bp,76:poke bp+of,1
57 if bp<(q9+462) then 39
58 pokebp,32:fl=0:goto82
59 s$="{SHIFT-*}AB↓{left}{left}{left}CED"
60 ifrnd(1)<.3thens$="TGF↓{left}{left}{left}HIJ"
61 poke b,32:print "{home}↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓{wht}"tab(rnd(1)*20)s$:ti$="000000":goto 39
62 if peek(bp)<>65 and peek(bp)<>71 then 67
63 poke bp,78:poke bp-1,79:poke bp+1,80:poke bp+21,81:poke bp+22,82:poke bp+23,78
64 for ll=1 to 20:next
65 poke bp,32:poke bp-1,32:poke bp+1,32:poke bp+21,32:poke bp+22,32:poke bp+23,32
66 fl=0:sc=sc+1:goto 82
67 if peek(bp)<>66 and peek(bp)<>70 and peek(bp)<>64 and peek(bp)<>84 then 70
68 if rnd(1)<.5 then poke bp-22,78:fl=0:goto 82
69 poke bp,78:poke bp+22,79:fl=0:goto 82
70 poke bp,32:for ii=1 to 20:next:poke bp,rnd(1)*4+78:for ii=1 to 50:next:fl=0:goto 82
71 for pp=xx to sp+22 step -22
72 poke pp,82:poke pp+of,1:next
73 poke sp,81
74 for pp=xx-22 to sp+22 step -22
75 poke pp,32:next
76 print "{home}↓↓↓↓you destroyed";sc
77 poke 198,0
78 print "↓{wht}press space for more"
79 get a$:if a$="" then 79
80 if a$=" " then poke 198,0:fl=0:goto 36
81 end
82 de=300-sc*5:if de<0 then de=1
83 for i=1 to int(ti/de)
84 s$="{SHIFT-*}AB↓{left}{left}{left}CED"
85 if rnd(1)<.3 then s$="TGF↓{left}{left}{left}HIJ"
86 print "{home}↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓{wht}"tab(rnd(1)*20)s$
87 next:ti$="000000"
88 goto 39
89 o$="":ford=1 to len(m$)
90 o$=right$(m$,d)+s$
91 print p$;o$:for de=1 to 50:next
92 o$=right$(m$,d)+"   ↓{left}{left}{left}   "
93 print p$;o$:for de= 1 to 50:next:next:return
94 print "{clr}you pilot a space-ship.....K"
95 print "↓it moves constantly   across the top of the  screen."
96 print "↓the '_' key changes   the direction of the  ship."
97 print "↓aliens...{SHIFT-*}AB & FGF"
98 print "         CED   HIJ"
99 print "↓move up the screen.   press the space bar tobomb them."
100 print "↓↓press space for more"
101 get i$:if i$="" then 101
102 print "{clr}when they get near thetop they will shoot atyou if they get the   chance."
103 print "↓they never miss...."
104 print "↓a hit on the centre   of the alien destroys it..."
105 print "↓a hit to either side  of an alien might get through the protectiveshields"
106 print "↓and hit the alien but the alien will still  be lethal"
107 print "↓↓press space for more"
108 get i$:if i$="" then 108
109 print "{clr}a bomb hitting the     shields will explode  leaving debris which will";
110 print " detonate bombs   falling on the same   path."
111 print "↓↓press space to start"
112 get i$:if i$="" then 112
113 goto 36

;alien-attack-3k.txt ==ffff==

(THIS IS A DRAFT)

FRIENDLY COMPUTERS CORPORATION

"A company that actually exists".

https://gravatar.com/comradevidak

README


Welcome to the first volume of the Friendly Computers Corporation
BASIC Program Listings!

Things to note:

# We recommend using VICE emulator.

# We recommend loading this VIC-20 PRG into emulator first.

# Hard mode: Don't, and type the program straight in!

# Patience Is A Virtue!

The fedi is as vibrant as always 💖

a wild vidak has appeared

The fedi is as vibrant as always 💖